Cum să mutați rapid elementele între două casete de listă din Excel?

Ați încercat vreodată să mutați articolele dintr-o casetă de listă în alta în casetele de listă, așa cum aveți nevoie, așa cum este prezentat mai jos? Aici voi vorbi despre această operațiune în Excel.

Mutați elementele între casetele de listă

Mutați elementele între casetele de listă

Nu există nicio funcție încorporată care vă poate ajuta să terminați treaba, dar am un cod VBA care poate face o favoare.

1. În primul rând, trebuie să creați o listă de date care vor fi afișate ca elemente în casetele de listă într-o nouă foaie care a fost numită Admin_Lists.

2. Apoi selectați aceste date și mergeți la Nume casetă pentru a le da un nume Lista de obiecte. Vedeți captura de ecran:

3. Apoi, într-o foaie care va conține cele două casete de listă, faceți clic pe Dezvoltator > Insera > Casetă listă (Active X Control), și desenați două casete de listă. Vedeți captura de ecran:

În cazul în care Dezvoltator fila este ascunsă panglica dvs., Cum se afișează / se afișează fila dezvoltator în panglica Excel 2007/2010/2013? acest articol vă va spune cum să îl arătați.

4. Apoi apasa Dezvoltator > Insera > Buton de comandă (Active X Control)și desenați patru butoane între două casete de listă. Vedeți captura de ecran:

Acum, pentru a redenumi cele patru butoane de comandă cu nume noi.

5. Selectați primul buton de comandă, faceți clic pe Proprietăţi, și în Proprietăţi , dați un nume BTN_moveAllRight la ea și tastați >> în caseta de text de lângă Legendă. Vedeți captura de ecran:

6. Repetați pasul 5 pentru a redenumi ultimul buton de comandă cu numele de mai jos și, de asemenea, tastați săgeata diferită în subtitrări. Vedeți captura de ecran:

BTN_MoveSelectedRight

BTN_moveAllLeft

BTN_MoveSelectedLeft

7. Faceți clic dreapta pe numele foii care conține casetele de listă și butoanele de comandă și selectați Afișați codul din meniul contextual. Vedeți captura de ecran:

8. Copiați și lipiți codul macro de mai jos în Module apoi salvați codul și închideți fișierul Microsoft Visual Basic pentru aplicații fereastră. Vezi captura de ecran

VBA: Mutați elementele între două casete de listă

Private Sub Worksheet_Activate()
'UpdatebyExtendoffice20171117
    Dim xCell As Range
    Dim xRg As Range
    Set xRg = Sheets("Admin_Lists").Range("ItemList")
    Me.ListBox1.Clear
    Me.ListBox2.Clear
    With Me.ListBox1
        .LinkedCell = ""
        .ListFillRange = ""
        For Each xCell In xRg
            If xCell <> "" Then
                .AddItem xCell.Value
            End If
        Next xCell
    End With
    Me.ListBox1.MultiSelect = fmMultiSelectMulti
    Me.ListBox2.MultiSelect = fmMultiSelectMulti
End Sub

Private Sub BTN_MoveSelectedLeft_Click()
    Call moveSigle(Me.ListBox2, Me.ListBox1)
End Sub

Private Sub BTN_MoveSelectedRight_Click()
    Call moveSigle(Me.ListBox1, Me.ListBox2)
End Sub

Private Sub BTN_moveAllLeft_Click()
    Call moveAll(Me.ListBox2, Me.ListBox1)
End Sub

Private Sub BTN_moveAllRight_Click()
    Call moveAll(Me.ListBox1, Me.ListBox2)
End Sub

Sub moveAll(xListBox1 As Object, xListBox2 As Object)
    Dim I As Long
    For I = 0 To xListBox1.ListCount - 1
        xListBox2.AddItem xListBox1.List(I)
    Next I
    xListBox1.Clear
End Sub

Sub moveSigle(xListBox1 As Object, xListBox2 As Object)
    Dim I As Long
    For I = 0 To xListBox1.ListCount - 1
        If I = xListBox1.ListCount Then Exit Sub
        If xListBox1.Selected(I) = True Then
            xListBox2.AddItem xListBox1.List(I)
            xListBox1.RemoveItem I
            I = I - 1
        End If
    Next
End Sub

9. Apoi mergeți la o altă foaie, apoi reveniți la foaia conține casetele de listă, acum puteți vedea datele listei au fost listate în prima casetă de listă. Și faceți clic pe butoanele de comandă pentru a muta articolele între două casete de listă.

Mutați selecția

Mutați toate