Note: The other languages of the website are Google-translated. Back to English

Cum se creează o listă dinamică de top 10 sau n în Excel?

O listă de top este folosită pentru a clasifica companiile sau persoanele fizice pe baza valorilor. Presupunând că aveți o listă cu notele elevilor dintr-o clasă, acum doriți să creați o listă dinamică de top 10 a studenților, așa cum se arată mai jos. În acest articol, voi introduce câteva formule pentru crearea unei liste de top 10 sau n într-o foaie de lucru Excel.


Creați o listă dinamică de top 10 în Excel

În Excel 2019 și versiunile anterioare, pentru a extrage lista de top 10 sau lista de top 10 cu criterii, ar trebui să aplicați următoarele formule:

Formule pentru a crea o listă dinamică de top 10

1. Mai întâi, ar trebui să extrageți primele 10 valori din intervalul de date, vă rugăm să utilizați formula de mai jos într-o celulă goală - G2 și trageți mânerul de umplere în jos pentru a obține primele 10 valori, vedeți captura de ecran:

=LARGE($B$2:$B$20,ROWS(B$2:B2))
notițe: În această formulă, B2: B20 este lista de date în care doriți să obțineți primele 10 valori și B2 este prima celulă din lista de date.

2. Apoi, continuați să aplicați următoarea formulă în celulă - F2 și apăsați Ctrl + Shift + Enter tastele împreună pentru a obține primul rezultat, vezi captura de ecran:

=INDEX($A$2:$A$20,SMALL(IF($B$2:$B$20=G2,ROW($B$2:$B$20)-ROW($B$1)),COUNTIF($G$2:G2,G2)))
notițe: În formula de mai sus, A2: A20 este lista de date din care doriți să extrageți numele celor mai importante 10 valori, B2: B20 este lista de date care conține toate valorile, G2 este celula cu cea mai mare valoare extrasă din coloană B și B1 este celula antet a listei de valori.

3. După ce obțineți primul rezultat, selectați celula formulei și trageți mânerul de umplere în jos pentru a obține alte nume simultan, vedeți captura de ecran:


Formule pentru a crea o listă dinamică de top 10 cu criterii

Uneori, poate fi necesar să obțineți lista de top 10 pe baza unor criterii. De exemplu, pentru a obține primele 10 nume și scoruri ale Class1, așa cum se arată mai jos.

1. Pentru a obține lista de top 10, ar trebui, de asemenea, să extrageți primele 10 scoruri cu această formulă:

=LARGE(IF($B$2:$B$25=$F$2,$C$2:$C$25),ROW(I2)-ROW(I$1))

2. Și apoi apăsați Ctrl + Shift + Enter tastele împreună pentru a obține primul rezultat, apoi trageți această formulă în jos pentru a afișa alte valori, vedeți captura de ecran:

3. Apoi, copiați și lipiți următoarea formulă în celula - I2 și apăsați Ctrl + Shift + Enter tastele simultan pentru a extrage primul rezultat, apoi trageți această formulă pentru a o completa în alte celule, iar primele 10 nume sunt afișate după cum se arată mai jos:

=INDEX($A$2:$A$25,SMALL(IF(($C$2:$C$25=J2)*($B$2:$B$25=$F$2),ROW($C$2:$C$25)-ROW($C$1)),COUNTIF(J2:$J$2,J2)))

Creați o listă dinamică de top 10 în Office 365

Formulele de mai sus pot fi greu de înțeles pentru noi, dacă utilizați Office 365, cu funcțiile sale INDEX, SORT și SEQUENCE, puteți crea formule simple pentru a finaliza această sarcină.

Formula pentru a crea o listă dinamică de top 10

Pentru a obține lista 10 de date, vă rugăm să utilizați formula de mai jos:

=INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2})

Și apoi, doar apăsați Intrați cheie, toate datele din primele 10 liste sunt afișate simultan, vezi captura de ecran:

sfaturi:

Funcția SORT:

=SORT(matrice, [index_sortare], [ordonare_sortare], [după_col])

  • mulțime: intervalul de celule pe care doriți să le sortați;
  • [sort_index]: Numărul coloanei sau rândului după care să sortați în matrice. De exemplu, pentru a sorta după a doua coloană a intervalului de date, indexul de sortare ar fi 2;
  • [ordinea de sortare]: Numărul 1 (sau omis) indică sortarea în ordine crescătoare; numărul -1, sortați în ordine descrescătoare;
  • [de_col]: Direcția sortării. TRUE, sortați după coloane, FALSE sau omis, sortați după rânduri.

În formulă, folosim funcția SORT astfel:

SORTARE(A2:B20,2,-1): Înseamnă să sortați intervalul de celule A2:A20 pe a doua coloană în ordine descrescătoare.


Funcția SEQUENCE:

=SEQUENCE(rânduri, [coloane], [start], [pas])

  • rânduri: numărul de rânduri de returnat,
  • [coloane]: numărul de coloane de returnat. Dacă este omisă, va returna o singură coloană.
  • [start]: primul număr din succesiune. Dacă este omisă, va începe la 1.
  • [Etapa]: incrementul dintre fiecare număr. Dacă este exclus, fiecare creștere va fi 1.

În această formulă, folosim SEQUENCE(10) pentru a crea o listă de la 1 la 10.

În cele din urmă, puneți ambele funcții SORT și SEQUENCE în funcția INDEX: =INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2}), aceasta va returna primele 10 înregistrări din intervalul de date și va returna coloanele 1 și 2.


Formula pentru a crea o listă dinamică de top 10 cu criterii

Pentru a afișa primele 10 liste cu criterii, ar trebui să încorporați funcția FILTER în funcția SORT astfel:

=INDEX(SORT(FILTER(A2:C25,B2:B25=F2),3,-1),SEQUENCE(10),{1,3})

Și doar apăsați Intrați cheie, toate datele din primele 10 liste pe baza criteriilor date sunt afișate simultan, vezi captura de ecran:

sfaturi:

Funcția FILTER:

=FILTER(matrice, include, [dacă_gol])

  • mulțime: intervalul de celule de filtrat.
  • include: Condiția pe care o utilizați pentru a filtra matricea pentru a obține un rezultat TRUE sau FALSE, astfel încât valorile TRUE să fie reținute în filtru.
  • [dacă_gol]: Valoarea care va fi afișată dacă nu se returnează niciun rezultat care se potrivește.

In aceasta formula: =FILTER(A2:C25,B2:B25=F2) este folosit pentru a filtra în intervalul A2:C25, unde valorile din B2:B25 sunt egale cu celula specifică F2.


Cele mai bune instrumente de productivitate Office

Kutools pentru Excel vă rezolvă majoritatea problemelor și vă crește productivitatea cu 80%

  • reutilizarea: Introduceți rapid formule complexe, diagrame și orice ai folosit anterior; Criptați celulele cu parola; Creați o listă de corespondență și trimiteți e-mailuri ...
  • Super Formula Bar (editați cu ușurință mai multe linii de text și formulă); Layout de citire (citiți și editați cu ușurință un număr mare de celule); Lipiți la interval filtrat...
  • Merge celule / rânduri / coloane fără a pierde date; Conținut de celule divizate; Combinați rânduri / coloane duplicate... Prevenirea celulelor duplicate; Comparați gamele...
  • Selectați Duplicat sau Unic Rânduri; Selectați Rânduri goale (toate celulele sunt goale); Super Find și Fuzzy Find în multe cărți de lucru; Selectare aleatorie ...
  • Copie exactă Mai multe celule fără modificarea referinței formulelor; Creați automat referințe la foi multiple; Introduceți gloanțe, Casete de selectare și multe altele ...
  • Extrageți textul, Adăugați text, eliminați după poziție, Eliminați spațiul; Creați și imprimați subtotaluri de paginare; Convertiți conținutul dintre celule și comentarii...
  • Super Filtru (salvați și aplicați scheme de filtrare altor foi); Sortare avansată după lună / săptămână / zi, frecvență și multe altele; Filtru special cu bold, italic ...
  • Combinați cărți de lucru și foi de lucru; Merge Tables pe baza coloanelor cheie; Împărțiți datele în mai multe foi; Conversia în loturi xls, xlsx și PDF...
  • Peste 300 de funcții puternice. Suportă Office / Excel 2007-2021 și 365. Acceptă toate limbile. Implementare ușoară în întreprinderea sau organizația dvs. Funcții complete Probă gratuită de 30 de zile. Garanție de returnare a banilor de 60 de zile.
fila kte 201905

Fila Office aduce interfața cu file în Office și vă face munca mult mai ușoară

  • Activați editarea și citirea cu file în Word, Excel, PowerPoint, Publisher, Access, Visio și Project.
  • Deschideți și creați mai multe documente în filele noi ale aceleiași ferestre, mai degrabă decât în ​​ferestrele noi.
  • Vă crește productivitatea cu 50% și reduce sute de clicuri de mouse pentru dvs. în fiecare zi!
fundul officetab
Comentarii (0)
Încă nu există evaluări. Fii primul care evaluează!
Nu există comentarii postate aici încă
Lăsa comentarii
Postare ca invitat
×
Evaluează această postare:
0   Caractere
Locații sugerate

Urmărește-ne

Copyright © 2009 - www.extendoffice.com. | Toate drepturile rezervate. Cu sprijinul ExtendOffice. | Harta site-ului
Microsoft și sigla Office sunt mărci comerciale sau mărci comerciale înregistrate ale Microsoft Corporation în Statele Unite și / sau în alte țări.
Protejat de Sectigo SSL