Cum se trimite un calendar mai multor destinatari individual în Outlook?

În mod normal, puteți trimite un calendar unui destinatar rapid și ușor utilizând Calendar de e-mail caracteristică în Outlook. Dacă doriți să trimiteți un calendar atașat ca fișier iCalendar la mai multe contacte individual, trebuie să îl trimiteți unul câte unul. În acest articol, voi vorbi despre o modalitate ușoară de a trimite un calendar către mai mulți destinatari individual în Outlook.

Trimiteți un calendar către mai mulți destinatari individual cu cod VBA

Trimiteți un calendar către mai mulți destinatari individual cu cod VBA

Pentru a trimite separat un calendar către mai mulți destinatari, următorul cod VBA vă poate ajuta, vă rugăm să procedați astfel:

1. Navigați la Contact și selectați contactele la care doriți să trimiteți calendarul.

2. Apoi țineți apăsat butonul ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

3. Clic Insera > Module, copiați și lipiți codul de mai jos în modulul gol deschis, vedeți captura de ecran:

Cod VBA: trimiteți un calendar mai multor destinatari individual ：

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. După introducerea codului, apoi apăsați F5 tasta pentru a rula acest cod și a Selectați Dosar se deschide caseta de dialog, selectați un calendar pe care doriți să-l trimiteți, vedeți captura de ecran:

5. Clic OK, și apoi specificați intervalul de date pe care doriți să îl trimiteți calendarului în următoarele casete de prompt, consultați captura de ecran:

6. Apoi, faceți clic OK, noile e-mailuri cu calendarul atașat au fost create după cum se arată în următoarea captură de ecran, apoi trebuie doar să le trimiteți unul câte unul.