Cum să răspundeți în mod normal în dosarul articolelor trimise din Outlook?

În mod normal, când faceți clic pe funcția Răspuns în folderul Elemente trimise pentru a trimite un alt mesaj suplimentar pentru persoanele pe care le-ați trimis, propria dvs. adresă de e-mail va fi afișată în câmpul Către după cum se arată în următoarea captură de ecran. Acest lucru poate fi deranjant pentru schimbarea adresei de fiecare dată. Cum ar putea face Outlook să utilizeze adresa destinatarului original, nu a ta?

doc răspunsuri trimise e-mailuri 1

Răspundeți în mod normal în folderul Elemente trimise din Outlook cu funcția Răspundeți tuturor

Răspundeți în mod normal în folderul Elemente trimise din Outlook cu cod VBA

Răspundeți în mod normal în folderul Elemente trimise din Outlook cu funcția Răspundeți tuturor

În Outlook, Răspunde la toate funcția vă poate ajuta să rezolvați această problemă, vă rugăm să procedați astfel:

Când trebuie să răspundeți la e-mailul trimis pentru a fi trimis din nou pentru a păstra adresa destinatarului original, faceți clic pe Răspunde la toate , iar adresa destinatarului original este localizată la La câmpul după cum se arată în următoarea captură de ecran:

doc răspunsuri trimise e-mailuri 2

Răspundeți în mod normal în folderul Elemente trimise din Outlook cu cod VBA

Uneori, puteți uita Răspunde la toate caracteristică atunci când răspundeți la mesajul trimis, astfel încât codul VBA de mai jos vă poate ajuta să răspundeți în mod normal în folderul Elemente trimise utilizând funcția Răspuns. Faceți pașii următori:

1. Țineți apăsat butonul ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

2. În Microsoft Visual Basic pentru aplicații fereastră, faceți dublu clic Această sesiune Outlook de la Project1 (VbaProject.OTM) pentru a deschide modul, apoi copiați și lipiți următorul cod în modulul gol.

Cod VBA: Răspundeți în mod normal în folderul Elemente trimise din Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

doc răspunsuri trimise e-mailuri 3

3. Apoi, salvați codul și reporniți Outlook pentru a obține efectul de cod, acum, când faceți clic răspuns pentru a retrimite un e-mail Obiecte trimise dosar, adresa destinatarului original este afișată în câmpul Către după cum aveți nevoie.