Cum să păstrați categoria în timp ce răspundeți sau redirecționați e-mailurile în Outlook? 

În mod normal, atunci când răspundeți sau redirecționați un e-mail pe care l-am clasificat, categoria va fi eliminată automat pe e-mailul trimis. Dacă doriți să păstrați categoria de e-mailuri trimise în răspuns sau redirecționare, acest articol va introduce o metodă de gestionare a acesteia.

Păstrați categoria în timp ce răspundeți sau redirecționați e-mailul cu codul VBA

---

Păstrați categoria în timp ce răspundeți sau redirecționați e-mailul cu codul VBA

1. Țineți apăsată tasta ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

2. În Microsoft Visual Basic pentru aplicații fereastră, faceți dublu clic Această sesiune Outlook de la Project1 (VbaProject.OTM) pentru a deschide modul, apoi copiați și lipiți următorul cod în modulul gol.

Cod VBA: păstrați categoria în timp ce răspundeți sau redirecționați e-mailul:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Apoi salvați și închideți această fereastră de cod, închideți și reporniți Outlook, acum, când răspundeți sau redirecționați un e-mail cu categorie, categoria va fi păstrată în mesajul de ieșire din Obiecte trimise, vezi captura de ecran: