Cum să ștergeți toate categoriile din Outlook?

Să presupunem că există o mulțime de articole care se aplică categoriei de culori din Outlook. Dacă trebuie să ștergeți toate aceste categorii din articole, cum ați putea face față acestei sarcini rapid și ușor în Outlook?

Ștergeți toate categoriile dintr-un anumit folder cu funcția Ștergeți toate categoriile

Ștergeți toate categoriile dintr-un anumit cont cu cod VBA

Ștergeți toate categoriile dintr-un anumit folder cu funcția Ștergeți toate categoriile

Dacă trebuie doar să ștergeți categoriile dintr-un anumit folder, vă rugăm să procedați astfel:

1. Faceți clic pe folderul în care doriți să eliminați categoriile de culori, apoi apăsați Ctrl + A pentru a selecta toate articolele.

2. Apoi faceți clic dreapta, apoi alegeți Clasificați > Ștergeți toate categoriile din meniul contextual, vezi captura de ecran:

3. Și apoi, toate categoriile de culori din acest folder specific au fost șterse simultan.

Ștergeți toate categoriile dintr-un anumit cont cu cod VBA

Pentru a șterge toate categoriile din toate articolele, cum ar fi e-mailuri, activități, contacte, note și așa mai departe dintr-un cont, codul VBA de mai jos vă poate face o favoare:

1. Faceți clic pe un e-mail al contului din care doriți să curățați toate categoriile, apoi țineți apăsat butonul ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

2. Clic Insera > Moduleși lipiți următoarea macro în fișierul Module Fereastră.

Cod VBA: ștergeți toate categoriile dintr-un anumit cont:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. Apoi, apăsați F5 tasta pentru al rula, apoi apare o casetă de prompt pentru a vă reaminti că toate categoriile din contul selectat au fost șterse, vedeți captura de ecran: