Cum să obțineți adresa de e-mail a expeditorului de la unul sau mai multe e-mailuri în Outlook?

Ați încercat vreodată să extrageți adresa de e-mail din câmpul „De la” al unuia sau mai multor e-mailuri primite în Outlook? Acest articol oferă un cod VBA pentru a vă ajuta să gestionați această sarcină.

Obțineți adresa de e-mail a expeditorului de la unul sau mai multe e-mailuri în Outlook

Rulați următorul cod VBA pentru a extrage adresa de e-mail din câmpul „De la” al unuia sau mai multor e-mailuri primite în Outlook.

1. Deschideți un folder de e-mail, selectați un mesaj de e-mail din care doriți să obțineți adresa de e-mail a expeditorului. apasă pe Alt + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

sfaturi: Pentru a selecta mai multe e-mailuri, țineți apăsat butonul Ctrl tasta și apoi selectați e-mailurile unul câte unul.

2. În Microsoft Visual Basic pentru aplicații fereastră, faceți clic pe Insera > Module, apoi copiați următorul cod VBA în fereastra Modul (cod).

Cod VBA: extrageți adresa de e-mail a expeditorului din unul sau mai multe e-mailuri în Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. clic Instrumente > Referinte, apoi verificați Runtime Microsoft Scripting cutie în Referințe – Proiect1 căsuță de dialog.

4. apasă pe F5 tasta pentru a rula codul. Apoi o Kutools pentru Outlook apare caseta de dialog, care listează toate adresele de e-mail ale expeditorului pentru e-mailurile selectate.

sfaturi:

Dacă trebuie să exportați lista de adrese într-un fișier txt, faceți clic pe Da butonul.

Sau faceți clic pe Nu pentru a încheia procesul.

5. După ce faceți clic pe Da buton, a Căutați dosarul apare caseta de dialog. Vă rugăm să alegeți un folder pentru a salva fișierul și faceți clic pe OK butonul.

6. În cele din urmă, a Kutools pentru Outlook va apărea caseta de dialog care vă va spune calea fișierului exportat. Clic OK să o închidă.

7. Accesați folderul în care este salvat fișierul exportat și deschideți fișierul .txt numit Adresă pentru a vedea adresele de e-mail ale expeditorului pentru e-mailurile selectate.