Cum să mutați automat diferite tipuri de elemente șterse în foldere diferite în Outlook?

În Outlook, toate tipurile de articole șterse (e-mailuri, sarcini, contacte etc.) vor fi mutate în folderul Elemente șterse. Dacă doriți să mutați elementele în foldere diferite în funcție de tipul de element din folderul Elemente șterse, așa cum se arată mai jos, cum puteți face acest lucru în Outlook?

Mutați automat diferite tipuri de articole șterse în foldere diferite cu codul VBA

Codul VBA de mai jos vă poate ajuta să mutați automat elementele șterse în dosare diferite, vă rugăm să procedați astfel:

1. Lansați Outlook, apoi țineți apăsat ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

2. Apoi, faceți dublu clic Această sesiune Outlook de la Proiect-Proiect1 panoul, apoi copiați și lipiți codul de mai jos în fereastra de cod goală:

Cod VBA: mutați automat diferite tipuri de elemente șterse în foldere diferite

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Apoi, salvați acest cod și reporniți Outlook pentru a activa acest cod.

4. De acum înainte, când ștergeți un articol, acesta va fi mutat în tipul corespunzător de folder de sub Elemente sterse folder automat.

5. Pentru a vizualiza rezultatul, vă rugăm să faceți clic pictograma din partea de jos a panoului folderului, apoi faceți clic Dosare pentru a extinde toate folderele din panou, vedeți capturile de ecran: