Cum să menții fereastra excel mereu deasupra?

V-ați dorit vreodată să vă păstrați ferestrele Excel întotdeauna deasupra și să nu fie acoperite de alte ferestre? Din păcate, Excel nu oferă o caracteristică pentru rezolvarea acestei sarcini. Dar, aici, vă pot oferi un cod VBA pentru a face față acestei sarcini.

Păstrați fereastra Excel întotdeauna deasupra cu codul VBA

Păstrați fereastra Excel întotdeauna deasupra cu codul VBA

Următorul cod VBA vă poate ajuta să mențineți fereastra Excel mereu deasupra, codul se aplică atât Office 32-bit, cât și Office 64-bit.

1. Țineți apăsat butonul ALT + F11 tastele pentru a deschide Fereastra Microsoft Visual Basic pentru aplicații.

2. Clic Insera > Moduleși lipiți următorul cod în Fereastra modulului.

Cod VBA: mențineți fereastra Excel întotdeauna deasupra

'Update 20140909
#If Win64 Then
    Public Declare PtrSafe Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As LongPtr, _
            ByVal hwndInsertAfter As LongPtr, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#Else
    Public Declare Function SetWindowPos _
        Lib "user32" ( _
            ByVal hwnd As Long, _
            ByVal hwndInsertAfter As Long, _
            ByVal x As Long, ByVal y As Long, _
            ByVal cx As Long, ByVal cy As Long, _
            ByVal wFlags As Long) _
    As Long
#End If
Public Const SWP_NOSIZE = &H1
Public Const SWP_NOMOVE = &H2
Public Const HWND_TOPMOST = -1
Public Const HWND_NOTOPMOST = -2
Sub ShowXLOnTop(ByVal OnTop As Boolean)
    Dim xStype As Long
    #If Win64 Then
        Dim xHwnd As LongPtr
    #Else
        Dim xHwnd As Long
    #End If
    If OnTop Then
        xStype = HWND_TOPMOST
    Else
        xStype = HWND_NOTOPMOST
    End If
    Call SetWindowPos(Application.hwnd, xStype, 0, 0, 0, 0, SWP_NOSIZE Or SWP_NOMOVE)
End Sub
Sub SetXLOnTop()
    ShowXLOnTop True
End Sub
Sub SetXLNormal()
    ShowXLOnTop False
End Sub

3. Apoi apăsați F5 tasta pentru a rula acest cod și a Macrocomenzi va apărea caseta de dialog, selectați SetXLOnTop și faceți clic pe Alerga butonul.

4. Și apoi fereastra Excel va fi întotdeauna deasupra altor aplicații.

notițe: Dacă doriți să readuceți fereastra Excel la normal, apăsați F5 tasta pentru a deschide fișierul Macrocomenzi dialog, alegeți SetXNormal și faceți clic Alerga.