În Excel, în timp ce funcția IF este esențială pentru testele logice de bază, condițiile complexe necesită adesea instrucțiuni IF imbricate pentru procesarea îmbunătățită a datelor. În acest ghid cuprinzător, vom acoperi elementele de bază ale IF imbricate în detaliu, de la sintaxă la aplicații practice, inclusiv combinații de IF imbricat cu condiții AND/OR. În plus, vom împărtăși cum să îmbunătățim lizibilitatea funcțiilor IF imbricate, precum și câteva sfaturi despre IF imbricat și vom explora alternative puternice, cum ar fi CĂUTARE V, IFS și altele, pentru a face operațiunile logice complexe mai ușor de utilizat și mai eficiente.

• Sintaxa IF imbricată
• Exemple practice de IF imbricate
• Imbricat dacă cu condiția AND / OR

• Faceți imbricat IF ușor de citit
• Ordinea funcțiilor IF imbricate
• Numerele și textul trebuie tratate diferit
• Limitările IF imbricate

• Folosind VLOOKUP
• Folosind IFS
• Folosind CHOOSE și MATCH

Funcția Excel IF vs. instrucțiuni IF imbricate

Funcția IF și instrucțiunile IF imbricate în Excel servesc unor scopuri similare, dar diferă semnificativ în complexitatea și aplicarea lor.

Utilizarea IF imbricată

Această secțiune demonstrează utilizarea de bază a instrucțiunilor IF imbricate în Excel, inclusiv sintaxa, exemple practice și modul de utilizare a acestora cu condiții AND sau OR.

Sintaxa IF imbricată

Înțelegerea sintaxei unei funcții este baza pentru aplicarea corectă și eficientă a acesteia în Excel. Să începem cu sintaxa instrucțiunilor imbricate if.

Sintaxă:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Argumente:

• Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
• Result1: This is the value returned if Condition1 is TRUE.
• Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
• Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
• Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
  
  In short, this expression can be interpreted as follows:
  Test condition1, if TRUE, return result1, if FALSE,
  test condition2, if TRUE, return result2, if FALSE,
  test condition3, if TRUE, return result3, if FALSE,
  return result4

Amintiți-vă, într-o structură IF imbricată, fiecare condiție ulterioară este evaluată numai dacă toate condițiile anterioare sunt FALSE. Această verificare secvențială este esențială pentru înțelegerea modului în care funcționează IF imbricate.

Exemple practice de IF imbricate

Acum, să ne aprofundăm în utilizarea IF imbricată cu două exemple practice.

Exemplul 1: Sistemul de notare

După cum se arată în captura de ecran de mai jos, să presupunem că aveți o listă cu scorurile studenților și doriți să atribuiți note pe baza acestor scoruri. Puteți utiliza IF imbricat pentru a îndeplini această sarcină.

Selectați o celulă goală (C2 în acest caz), introduceți următoarea formulă și apăsați Intrați pentru a obține rezultatul. Apoi trageți Mâner de umplere jos pentru a obține restul rezultatelor.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))

Exemplul 2: Calculul comisionului de vânzări

Imaginați-vă un scenariu în care reprezentanții de vânzări primesc comisioane diferite în funcție de realizările lor de vânzări. După cum se arată în captura de ecran de mai jos, doriți să calculați comisionul unui agent de vânzări pe baza acestor diferite praguri de vânzări, iar declarațiile IF imbricate vă pot ajuta în acest sens.

Selectați o celulă goală (C2 în acest caz), introduceți următoarea formulă și apăsați Intrați pentru a obține rezultatul. Apoi trageți Mâner de umplere jos pentru a obține restul rezultatelor.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Imbricat dacă cu condiția AND / OR

În această secțiune, modific primul exemplu de mai sus „sistemul de notare” pentru a demonstra cum să combinați IF imbricat cu condiția AND sau OR în Excel. În exemplul de notare revizuită, am introdus o condiție suplimentară bazată pe „Rata de prezență”.

Folosind imbricat if cu condiția AND

Dacă un student îndeplinește atât criteriile de punctaj, cât și de prezență, va primi un spor de notă. De exemplu, unui student al cărui punctaj este de 60 sau mai mare și a cărui rată de prezență este de 95% sau mai mult, i se va îmbunătăți nota cu un nivel, cum ar fi de la A la A+, de la B la B+ și așa mai departe. Cu toate acestea, dacă rata de participare este sub 95%, notarea va urma criteriile originale bazate pe scor. În astfel de cazuri, trebuie să folosim o instrucțiune IF imbricată cu o condiție AND.

Selectați o celulă goală (D2 în acest caz), introduceți următoarea formulă și apăsați Intrați pentru a obține rezultatul. Apoi trageți Mâner de umplere jos pentru a obține restul rezultatelor.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Folosind imbricat if cu condiția SAU

În acest caz, nota unui student va crește cu un nivel dacă scorul său este de 95 sau mai mare sau dacă rata de prezență este de 95% sau mai mult. Iată cum îl putem realiza folosind condiții imbricate IF și OR.

Selectați o celulă goală (D2 în acest caz), introduceți următoarea formulă și apăsați Intrați pentru a obține rezultatul. Apoi trageți Mâner de umplere jos pentru a obține restul rezultatelor.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Sfaturi și trucuri pentru IF imbricat

Această secțiune acoperă patru sfaturi și trucuri utile pentru IF imbricate.

Faceți imbricat IF ușor de citit

O instrucțiune IF imbricată tipică poate părea compactă, dar poate fi greu de descifrat.

În formula următoare, este o provocare să identifici rapid unde se termină o afecțiune și unde începe alta, mai ales pe măsură ce complexitatea crește.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Soluție: Adăugarea întreruperi de linie și indentare

Pentru a face IF imbricat ușor de citit, puteți împărți formula în mai multe linii, fiecare IF imbricat pe o linie nouă. În formulă, pur și simplu plasați cursorul înaintea IF și apăsați tastele Alt + Enter.

După ruperea formulei de mai sus, se va afișa după cum urmează:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Acest format face mai clar unde se află fiecare condiție și rezultatul corespunzător, îmbunătățind lizibilitatea formulei.

Ordinea funcțiilor IF imbricate

Ordinea condițiilor logice într-o formulă IF imbricată este crucială, deoarece determină modul în care Excel evaluează aceste condiții și afectează astfel rezultatul final al formulei.

Formula corectă

În exemplul Sistemului de notare, folosim următoarea formulă pentru a atribui note pe baza scorurilor.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Excel evaluează secvențial condițiile dintr-o formulă IF imbricată, de la prima condiție până la ultima. Această formulă verifică mai întâi cel mai mare prag de scor (>=90 pentru un „A”) și apoi trece la pragurile inferioare. Se asigură că un scor este comparat cu cea mai mare notă pentru care se califică. Dacă prima condiție este adevărată (A2>=90), returnează „A” și nu evaluează alte condiții.

Formula ordonată incorectă

Dacă ordinea condițiilor ar fi inversată, începând cu cel mai mic prag, ar returna rezultate incorecte.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

În această formulă incorectă, un scor de 95 ar îndeplini imediat prima condiție B2>=60 și i se atribuie incorect nota „D”.

Numerele și textul trebuie tratate diferit

Această secțiune vă va arăta cum numerele și textul sunt tratate diferit în instrucțiunile IF imbricate.

Numere

Numerele sunt folosite pentru comparații și calcule aritmetice. În instrucțiunile IF imbricate, puteți compara direct numere folosind operatori precum >, <, =, >= și <=.

Text

În instrucțiunile IF imbricate, textul ar trebui să fie cuprinse între ghilimele duble. Vezi A, B, C, D și F în următoarea formulă:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Limitările IF imbricate

Această secțiune listează câteva limitări și dezavantaje ale FI imbricate.

Complexitate și lizibilitate:

Deși Excel vă permite să cuibăriți până la 64 de funcții IF diferite, nu este deloc recomandabil să faceți acest lucru. Cu cât sunt mai multe niveluri de cuibărit, cu atât formula devine mai complexă. Acest lucru poate duce la formule greu de citit, înțeles și întreținut.

predispus la erori:

Mai mult, instrucțiunile IF imbricate complexe pot deveni predispuse la erori și pot fi dificil de depanat sau modificat.

Greu de extins sau scalat:

Dacă logica dvs. se schimbă sau trebuie să adăugați mai multe condiții, IF-urile profund imbricate pot fi greu de modificat sau extins.

Înțelegerea acestor limitări este cheia pentru utilizarea eficientă a instrucțiunilor IF imbricate în Excel. Adesea, combinarea FI imbricate cu alte funcții sau căutarea unor abordări alternative poate duce la soluții mai eficiente și mai ușor de întreținut.

Alternative la Imbricate IF

Această secțiune listează mai multe funcții din Excel care pot fi utilizate ca alternative la instrucțiunile IF imbricate.

Folosind VLOOKUP

Puteți folosi funcția CĂUTARE VL în loc de instrucțiuni IF imbricate pentru a realiza cele două exemple practice de mai sus. Iată cum o poți face:

Exemplul 1: Sistem de notare cu VLOOKUP

Aici voi arăta cum să utilizați VLOOKUP pentru a atribui note pe baza scorurilor.

Pasul 1: Creați un tabel de căutare pentru note

În primul rând, trebuie să creați un tabel de căutare (cum ar fi E1:F6 în acest caz) pentru intervalul de scor și notele corespunzătoare. notițe: Scorurile din prima coloană a tabelului trebuie sortate în ordine crescătoare.

Pasul 2: Aplicați funcția CĂUTARE V pentru a atribui note

Selectați o celulă goală (C2 în acest caz), introduceți următoarea formulă și apăsați tasta Intrați cheie pentru a obține clasa întâi. Selectați această celulă de formulă și trageți-o Mâner de umplere jos pentru a lua restul notelor.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Exemplul 2: Calculul comisionului de vânzări cu VLOOKUP

De asemenea, puteți utiliza VLOOKUP pentru a realiza calculul comisionului de vânzări în Excel. Vă rugăm să faceți după cum urmează.

Pasul 1: Creați un tabel de căutare pentru note

În primul rând, trebuie să creați un tabel de căutare pentru vânzări și rata de comision corespunzătoare, cum ar fi E2:F4 în acest caz. notițe: Vânzările din prima coloană a tabelului trebuie sortate în ordine crescătoare.

Pasul 2: Aplicați funcția CĂUTARE V pentru a atribui note

Selectați o celulă goală (C2 în acest caz), introduceți următoarea formulă și apăsați tasta Enter pentru a obține primul comision. Selectați această celulă de formulă și trageți în jos mânerul de umplere pentru a obține restul rezultatelor.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Folosind IFS

Funcția IFS simplifică procesul prin eliminarea necesității de imbricare și face formulele mai ușor de citit și gestionat. Îmbunătățește lizibilitatea și simplifică gestionarea mai multor verificări condiționate. Pentru a utiliza funcția IFS, asigurați-vă că utilizați Excel 2019 sau o versiune ulterioară sau aveți un abonament Office 365. Să vedem cum poate fi aplicat în exemple practice.

Exemplul 1: Sistem de notare cu IFS

Presupunând aceleași criterii de notare ca și înainte, funcția IFS poate fi utilizată după cum urmează:

Selectați o celulă goală, cum ar fi C2, introduceți următoarea formulă și apăsați Intrați pentru a obține primul rezultat. Selectați această celulă rezultat și trageți-o Mâner de umplere jos pentru a obține restul rezultatelor.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Exemplul 2: Calculul comisionului de vânzări cu IFS

Pentru scenariul de calcul al comisionului de vânzări, funcția IFS se aplică după cum urmează:

Selectați o celulă goală, cum ar fi C2, introduceți următoarea formulă și apăsați Intrați pentru a obține primul rezultat. Selectați această celulă rezultat și trageți-o Mâner de umplere jos pentru a obține restul rezultatelor.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Folosind CHOOSE și MATCH

Abordarea CHOOSE și MATCH poate fi mai eficientă și mai ușor de gestionat în comparație cu instrucțiunile IF imbricate. Această metodă simplifică formula și face actualizările sau modificările mai simple. Mai jos voi demonstra cum să utilizați o combinație a funcțiilor ALEGE și MATCH pentru a gestiona cele două exemple practice din acest articol.

Exemplul 1: Sistem de notare cu ALEGE și MATCH

Puteți utiliza combinația dintre funcțiile ALEGE și MATCH pentru a atribui note pe baza unor scoruri diferite.

Pasul 1: Creați o matrice de căutare cu valori de căutare

În primul rând, trebuie să creați o serie de celule care să conțină valorile de prag prin care MATCH le va căuta, cum ar fi $E$2:$E$6 în acest caz. notițe: Numerele din acest interval trebuie sortate în ordine crescătoare pentru ca funcția MATCH să funcționeze corect atunci când se utilizează un tip de potrivire aproximativă.

Pasul 2: Aplicați ALEGE și MATCH pentru a atribui note

Selectați o celulă goală (C2 în acest caz), introduceți următoarea formulă și apăsați tasta Intrați cheie pentru a obține clasa întâi. Selectați această celulă de formulă și trageți-o Mâner de umplere jos pentru a obține restul rezultatelor.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Exemplul 2: Calculul comisionului de vânzări cu IFS

Utilizarea combinației ALEGE și MATCH pentru un calcul al comisionului de vânzări poate fi, de asemenea, eficientă, mai ales atunci când ratele comisioanelor se bazează pe praguri de vânzări specificate. Să vedem cum putem face.

Pasul 1: Creați o matrice de căutare cu valori de căutare

În primul rând, trebuie să creați o serie de celule care să conțină valorile de prag prin care MATCH le va căuta, cum ar fi $E$2:$E$4 în acest caz. notițe: Numerele din acest interval trebuie sortate în ordine crescătoare pentru ca funcția MATCH să funcționeze corect atunci când se utilizează un tip de potrivire aproximativă.

Pasul 2: Aplicați ALEGE și MATCH pentru a obține rezultate

Selectați o celulă goală (C2 în acest caz), introduceți următoarea formulă și apăsați tasta Intrați cheie pentru a obține clasa întâi. Selectați această celulă de formulă și trageți-o Mâner de umplere jos pentru a obține restul rezultatelor.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

În concluzie, stăpânirea instrucțiunilor IF imbricate în Excel este o abilitate valoroasă care vă îmbunătățește capacitatea de a gestiona scenarii logice complexe în analiza datelor și procesele de luare a deciziilor. În timp ce IF-urile imbricate sunt puternice pentru operațiuni logice complexe, este important să fiți atenți la limitările lor. Alternativele mai simple precum VLOOKUP, IFS și CHOOSE with MATCH pot oferi soluții mai simplificate în anumite scenarii. Înarmat cu aceste informații, acum puteți aplica cu încredere cele mai potrivite tehnici Excel pentru sarcinile dvs. de analiză a datelor, asigurând claritate, acuratețe și eficiență în foile de calcul. Pentru cei dornici să aprofundeze capacitățile Excel, site-ul nostru web se mândrește cu o mulțime de tutoriale. Descoperiți mai multe sfaturi și trucuri Excel aici.

Articole pe aceeaşi temă