Excel CHOOSE funcţie
- Ex1 - Utilizare de bază: folosind CHOOSE funcționează singur pentru a alege valoarea din argumentul listei
- Ex2 - Returnează rezultate diferite pe baza mai multor condiții
- Ex3 - Returnează diferite rezultate calculate pe baza condițiilor
- Ex4 - Alegeți aleatoriu din listă
- Ex5 - Combinați CHOOSE și VLOOKUP funcții pentru a returna valoarea în coloana din stânga
- Ex6 - Întoarceți ziua săptămânii sau luna pe baza datei date
- Ex7 - Reveniți la următoarea zi de lucru / weekend, pe baza zilei de azi
Descriere
CHOOSE funcția returnează o valoare din lista argumentului valorii pe baza numărului de index dat. De exemplu, CHOOSE(3,”Apple”,”Peach”,”Orange”) returnează portocaliu, numărul de index este 3, iar portocaliu este a treia valoare după numărul de index din funcție.
sintaxă și Argumente
Sintaxa formulei
CHOOSE(index_num, value1, [value2], …) |
Argumente
|
Value1, value2… Pot fi numere, texte, formule, referințe de celule sau nume definit.
Valoarea retur
CHOOSE funcția returnează o valoare dintr-o listă pe baza poziției date.
Utilizare și exemple
În această parte, enumer câteva exemple simple, dar reprezentative, pentru a explica utilizarea CHOOSE Funcția.
Ex1 - Utilizare de bază: folosind CHOOSE funcționează singur pentru a alege valoarea din argumentul listei
Formula 1:
=CHOOSE(3,"a","b","c","d")
Returnare: c, care este al treilea argument după index_num din 3 în CHOOSE Funcția.
Notă: folosind ghilimele duble care înconjoară valoarea dacă este text.
Formula 2:
=CHOOSE(2,A1,A2,A3,A4)
Întoarcere: Kate, valoarea A2. Deoarece index_num este 2, iar A2 este a doua valoare în CHOOSE Funcția.
Formula 3:
=CHOOSE(4,8,9,7,6)
Întoarcere: 6, cel de-al 4-lea argument din funcție.
Ex2 - Returnează rezultate diferite pe baza mai multor condiții
Presupunând că aveți o listă de abateri pentru fiecare produs care trebuia etichetată în funcție de condițiile prezentate mai jos în imaginea de mai jos.
De obicei, puteți utiliza funcția IF pentru a gestiona, dar aici vă prezint cum să utilizați CHOOSE funcție pentru a rezolva cu ușurință această problemă
Formula:
=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")
Explica:
(B7>0)+(B7>1)+(B7>5): index_num, B7 este 2, care este mai mare de 0 și 1, dar mai puțin de 5, deci obținem rezultatul intermediar:
=CHOOSE(True+Ture+False,"Top","Middle","Bottom")
După cum știm, Adevărat = 1, False = 0, astfel formula poate fi văzută ca:
=CHOOSE(1+1+0,"Top","Middle","Bottom")
apoi
=CHOOSE(2,"Top","Middle","Bottom")
Rezultat: mijlociu
Ex3 - Returnează diferite rezultate calculate pe baza condițiilor
Presupunând că trebuie să calculați reducerile pentru fiecare produs pe baza sumei și a prețului, după cum se arată în imaginea de mai jos:
Formula:
=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
Explica:
(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 este 102, care este mai mare de 100 dar mai puțin de 201, deci în această parte, returnează rezultatul prezentat ca:
=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
apoi
=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)
B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: valorile dintre care să alegeți, reducerea este egală cu prețul * suma * procentul de reducere, deoarece aici index_num este 2, alege B8 * C8 * 0.2
Returnează: 102 * 2 * 0.2 = 40.8
Ex4 - Alegeți aleatoriu din listă
În Excel, uneori, poate fi necesar să alegeți aleatoriu o valoare dintr-o listă dată, CHOOSE funcția poate rezolva această sarcină.
Alegeți aleatoriu o valoare dintr-o listă:
Formula:
=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)
Explica:
RANDBETWEEN(1,5): index_num, obțineți în mod aleatoriu un număr între 1 și 5
$D$2,$D$3,$D$4,$D$5,$D$6: lista valorilor din care să alegeți
Ex5 - Combinați CHOOSE și VLOOKUP funcții pentru a returna valoarea în coloana din stânga
În general, folosim funcția VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) pentru a returna o valoare bazată pe o valoare dată dintr-un interval de tabel. Dar cu VLOOKUP funcția, va returna o valoare de eroare în timp ce coloana de returnare este în stânga coloanei de căutare, după cum se arată în imaginea de mai jos:
În acest caz, puteți combina CHOOSE funcție cu funcția VLOOKUP pentru a rezolva problema.
Formula:
=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)
Explica:
CHOOSE({1,2},B1:B7,A1:A7): ca argument table_range în funcția VLOOKUP. {1,2} înseamnă să afișați 1 sau 2 ca argument index_num bazat pe argumentul col_num în funcția VLOOKUP. Aici, col_num în funcția VLOOKUP este 2, deci CHOOSE afișarea funcției ca CHOOSE(2, B1:B7,A1:A7), înseamnă să alegeți valoarea dintre A1: A7.
Ex6 - Întoarceți ziua săptămânii sau luna pe baza datei date
Cu CHOOSE funcția, puteți, de asemenea, să returnați ziua și săptămâna relativă pe baza unei date date.
Formula 1: reveniți în ziua săptămânii cu o dată
=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")
Explica:
WEEKDAY(): argumentul index_num, pentru a obține numărul zilei săptămânii la data dată, de exemplu, WEEKDAY (A5) returnează 6, apoi argumentul index_num este 6.
"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": argumentele listei de valori, începeți cu „duminică”, deoarece numărul săptămânii „1” indică „duminică”.
Formula 2: returnează luna cu o dată
=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")
Explica:
MONTH(): argumentul index_num, care obține numărul lunii de la data dată, de exemplu, LUNA (A5) returnează 3.
Ex7 - Reveniți la următoarea zi de lucru / weekend, pe baza zilei de azi
În munca de zi cu zi, vă recomandăm să calculați următoarea zi de lucru sau weekend în funcție de ziua de azi. Aici CHOOSE funcția vă poate face, de asemenea, o favoare.
De exemplu, astăzi este 12, joi, acum trebuie să obțineți următoarea zi lucrătoare și weekend.
Formula 1: obțineți data de astăzi
=TODAY()
Rezultat: 12
Formula 2: obțineți numărul zilei săptămânii de astăzi
=WEEKDAY(TODAY())
Rezultat: 5 (în timp ce astăzi este 12)
Se afișează lista numerelor din ziua săptămânii, după cum se arată mai jos:
Formula 3: obține următoarea zi lucrătoare
=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)
Explica:
Today(): returnează data curentă
WEEKDAY(TODAY()): argumentul index_num din CHOOSE funcție, obțineți numărul din ziua săptămânii de astăzi, de exemplu, duminica este 1, luni este 2 ...
1,1,1,1,1,3,2: argumentul listei de valori din CHOOSE funcţie. De exemplu, dacă ziua săptămânii (azi ()) returnează 1 (duminică), alege 1 din lista valorilor, apoi întreaga formulă se schimbă în = Azi () + 1, ceea ce înseamnă să adăugați o zi pentru a reveni luni viitoare. Dacă ziua săptămânii (azi ()) returnează 1 (vineri), alege 6 din lista de valori, deoarece vinerea este la 3 zile de luni următoare.
Rezultat (în timp ce astăzi este 12):
=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)
= 12 + 20
= 12
Formula 4: obține următoarea zi de weekend
=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)
Explica:
6,5,4,3,2,1,1: argumentul listei de valori din CHOOSE funcţie. De exemplu, dacă ziua săptămânii (azi ()) returnează 1 (duminică), alege 6 din lista de valori, atunci întreaga formulă se schimbă în = Azi () + 6, ceea ce înseamnă să adăugați 6 zile și să reveniți sâmbăta viitoare.
Rezultat:
=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)
= 12 + 20
= 12
Cele mai bune instrumente de productivitate Office
Kutools pentru Excel - Vă ajută să vă distingeți de mulțime
Kutools pentru Excel se mândrește cu peste 300 de caracteristici, Asigurați-vă că ceea ce aveți nevoie este la doar un clic distanță...
Fila Office - Activați lectura și editarea cu file în Microsoft Office (includeți Excel)
- O secundă pentru a comuta între zeci de documente deschise!
- Reduceți sute de clicuri de mouse pentru dvs. în fiecare zi, spuneți adio de la mâna mouse-ului.
- Vă crește productivitatea cu 50% atunci când vizualizați și editați mai multe documente.
- Aduce file eficiente la Office (inclusiv Excel), la fel ca Chrome, Edge și Firefox.