Împărțiți dimensiunile în lungime, înălțime și lățime individuale
Acest articol explică cum să împărțiți dimensiunile dintr-o celulă în trei părți (dimensiuni individuale care includ lungimea, înălțimea și lățimea).
Cum să împărțiți dimensiunile în trei părți?
Pentru a împărți dimensiunile în lungime, înălțime și lățime individuale, trebuie să aplicați separat trei formule diferite.
Formula generică de extragere a primei dimensiuni
=LEFT(text,FIND("char",text)-1)
Formula generică de extragere a doua dimensiune
=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))
Formula generică de extragere a celei de-a treia dimensiuni
=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))
Argumente ale formulelor de mai sus
Text: Șirul pe care doriți să extrageți numărul dat de caractere din acesta. Poate fi:
- 1. Textul cuprins între ghilimele;
- 2. Sau o referință la o celulă care conține textul.
Char: Personajul pe care veți împărți dimensiunile pe baza.
Cum se utilizează aceste formule?
În primul rând, trebuie să obținem prima dimensiune.
1. Selectați o celulă necompletată pentru a afișa prima dimensiune.
2. Introduceți formula de mai jos și apăsați tasta Intrați cheie. Selectând celula de rezultat și trageți mânerul de umplere pentru a aplica formula altor celule după cum aveți nevoie.
=LEFT(B5,FIND("x",B5)-1)
Apoi, vom împărți a doua dimensiune după cum urmează.
1. Selectați o celulă necompletată pentru a afișa a doua dimensiune.
2. Introduceți formula de mai jos și apăsați tasta Intrați cheie. Selectând celula de rezultat și trageți mânerul de umplere pentru a aplica formula altor celule după cum aveți nevoie.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
În cele din urmă, obțineți ultima dimensiune
1. Selectați o celulă necompletată pentru a afișa ultima dimensiune.
2. Introduceți formula de mai jos și apăsați tasta Intrați cheie. Selectând celula de rezultat și trageți mânerul de umplere pentru a aplica formula altor celule după cum aveți nevoie.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
Cum funcționează aceste formule?
=LEFT(B5,FIND("x",B5)-1)
1. FIND("x",B5)-1: Funcția FIND obține poziția primului „x” în B5. Pentru a obține prima dimensiune fără primul „x”, trebuie să scădeți 1. Apoi rezultatul este 4-1 = 3.
2. LEFT(B5,3): Funcția STÂNGA extrage 3 caractere începând din partea stângă a B5 și returnează rezultatul ca 100.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
1. FIND("x",B5)+1: Funcția FIND localizează primul „x” din B5. Deoarece trebuie să obțineți a doua dimensiune după primul „x”, aici este necesară adăugarea 1. Apoi rezultatul este 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): Funcția SUBSTITUTE înlocuiește al doilea „x” din B5 cu „@” și returnează rezultatul ca 100x50 @ 300;
- FIND("@",100x50@300): Funcția Găsiți aici obține poziția caracterului "@" în textul 100x50 @ 300 și returnează rezultatul ca 7.
3. (FIND("x",B5)+1): După cum s-a menționat pasul 1 de mai sus, aici funcția FIND localizează primul „x” din B5 și adaugă 1 pentru a returna rezultatul ca 5.
4. MID(B5,5,7-(5)): Funcția MID extrage două caractere (7-5 = 2) începând cu al cincilea caracter al textului din B5. Și întoarceți rezultatul final ca 50.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
1. LEN(B5): Funcția LEN calculează lungimea totală a șirului în B5 și returnează rezultatul ca 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): Funcția SUBSTITUTE înlocuiește al doilea „x” din B5 cu „@” și returnează rezultatul ca 100x50 @ 300;
- FIND("@",100x50@300): Funcția FIND localizează aici „@” în textul 100x50 @ 300 și returnează rezultatul ca 7.
3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10-7) Lungimea totală a șirului de text din celula B5 scade primele 7 caractere și returnează rezultatul ca 3.
4. RIGHT(B5,3): Și apoi funcția DREAPTA extrage 3 caractere începând din partea dreaptă a B5 și returnează a treia dimensiune ca 300.
Funcții conexe
Funcția STÂNGA Excel
Funcția STÂNGA extrage numărul dat de caractere din partea stângă a unui șir furnizat.
Funcția Excel MID
Funcția MID este utilizată pentru a găsi și a returna un număr specific de caractere din mijlocul șirului de text dat.
Funcția Excel DREAPTA
Funcția DREAPTA extrage un anumit număr de caractere din partea dreaptă a șirului de text.
Funcția Excel FIND
Funcția FIND este utilizată pentru a găsi un șir într-un alt șir și returnează poziția inițială a șirului în altul.
Funcția Excel LEN
Funcția LEN returnează numărul de caractere dintr-un șir de text.
Funcția Excel SUBSTITUTE
Funcția SUBSTITUT Microsoft Excel înlocuiește textul sau caracterele dintr-un șir de text cu alt text sau caractere.
Formule conexe
Împărțiți dimensiunile în două părți în Excel
Acest articol explică modul de utilizare a formulei pentru a împărți dimensiunile într-o celulă în două părți fără unități (lungime și lățime individuale).
Separați numerele de unitățile de măsură
Acest articol explică modul de utilizare a formulei pentru a separa numerele de unitățile de măsurare.
Cele mai bune instrumente de productivitate Office
Kutools pentru Excel - Vă ajută să vă distingeți de mulțime
Kutools pentru Excel se mândrește cu peste 300 de caracteristici, Asigurați-vă că ceea ce aveți nevoie este la doar un clic distanță...
Fila Office - Activați lectura și editarea cu file în Microsoft Office (includeți Excel)
- O secundă pentru a comuta între zeci de documente deschise!
- Reduceți sute de clicuri de mouse pentru dvs. în fiecare zi, spuneți adio de la mâna mouse-ului.
- Vă crește productivitatea cu 50% atunci când vizualizați și editați mai multe documente.
- Aduce file eficiente la Office (inclusiv Excel), la fel ca Chrome, Edge și Firefox.
