Cum să marcați automat e-mailurile pe baza unui atașament specific din Outlook?

Când primiți câteva e-mailuri cu atașament important specific, poate fi necesar să le semnalizați, astfel încât să le puteți găsi rapid și ușor pentru flux. În acest articol, voi vorbi despre o modalitate ușoară de a semnaliza automat e-mailurile care sunt atașate cu nume specifice.

Semnalează automat e-mailurile pe baza unui atașament specific cu codul VBA

---

Semnalează automat e-mailurile pe baza unui atașament specific cu codul VBA

Pentru a marca automat e-mailurile care conțin atașamentul specific, vă rugăm să aplicați următorul cod VBA:

1. Lansați Outlook, apoi țineți apăsat butonul ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

2. În Microsoft Visual Basic pentru aplicații fereastră, faceți dublu clic Această sesiune Outlook de la Project1 (VbaProject.OTM) pentru a deschide un nou mod, apoi copiați și lipiți următorul cod în modulul gol.

Cod VBA: semnalează automat e-mailurile pe baza unui atașament specific:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

notițe: În codul de mai sus, puteți modifica extensia de fișier și numele fișierului atașat după nevoile dvs.

3. Apoi salvați codul și reporniți Outlook pentru a face efectul codului, acum, când primiți e-mailurile cu numele atașamentelor care conțin textul specificat, Outlook va semnaliza automat acest e-mail pentru urmărire, a se vedea captura de ecran: