Cum se imprimă sarcini pe categorii în Outlook?

Presupunând că există diverse categorii de culori în sarcinile dvs. Outlook și acum doriți să imprimați listele de sarcini pe baza categoriilor din diferite pagini. Cum ați putea rezolva această sarcină în Outlook?

Imprimați manual sarcini bazate pe categorii din diferite pagini, una câte una

Imprimați activități bazate pe categorii din diferite pagini cu cod VBA

Imprimați manual sarcini bazate pe categorii din diferite pagini, una câte una

În Outlook, puteți imprima manual sarcinile pe baza diferitelor categorii din pagini diferite, pe rând, vă rugăm să procedați astfel:

1. Lansați Outlook și accesați panoul Task și selectați folderul de activități pe care doriți să îl imprimați, apoi apăsați Ctrl + E pentru a activa Caută caseta, apoi sub Caută fila, faceți clic pe clasificate pictogramă și alegeți o categorie de culori pe care trebuie să o imprimați, vedeți captura de ecran:

sarcini de tipărire doc după categoria 1

2. Și apoi, toate sarcinile cu categoria de culoare specifică sunt listate simultan, vezi captura de ecran:

sarcini de tipărire doc după categoria 2

3. Apoi, continuați să faceți clic Fișier > pentru a imprima această listă de sarcini, după cum se arată în următoarea captură de ecran:

sarcini de tipărire doc după categoria 3

4. Repetați pașii de mai sus pentru a imprima manual câte o listă de sarcini cu celelalte categorii de culori.

Imprimați activități bazate pe categorii din diferite pagini cu cod VBA

Iată un cod VBA care vă poate ajuta să imprimați sarcinile bazate pe categorie în diferite pagini simultan, vă rugăm să parcurgeți pașii următori:

1. Mergeți la Sarcină și selectați folderul de activități pe care doriți să îl imprimați.

2. Apoi, țineți apăsat butonul ALT + F11 tastele pentru a deschide Microsoft Visual Basic pentru aplicații fereastră.

3. Apoi, faceți clic Insera > Module, copiați și lipiți codul de mai jos în modulul gol deschis:

Cod VBA: tipăriți activități bazate pe categorii din diferite pagini:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Apoi apasa Instrumente > Referinte în Microsoft Visual Basic pentru aplicații fereastră, în fereastra ieșită Referințe-Proiect1 casetă de dialog, bifați Biblioteca de obiecte Microsoft Excel și Runtime Microsoft Scripting opțiuni din Referințe disponibile casetă listă, vezi captura de ecran:

sarcini de tipărire doc după categoria 4

5. Apoi, faceți clic OK butonul, acum, apăsați F5 tasta pentru a rula acest cod, după terminarea codului, listele de sarcini cu categorii diferite vor fi tipărite în pagini diferite.